Allunaggio – TI99/4A – TI Extended Basic

Rivista: PC Personal Computer – Anno: 1983 – Numero: 8 – Trascrizione: Francesco Fiorentini

Primo listato della rivista PC Personal Computer anno II numero 2:
https://www.retromagazine.net/pc-personal-computer-club-anno-iI-numero-2/

“Allunaggio” è un classico esempio di codice BASIC d’epoca, tipico dei primi simulatori lunari. Nonostante la sua semplicità e i limiti tecnici, può ancora regalare qualche minuto di divertimento a chi cerca la giusta strategia per bruciare il carburante al momento giusto.

Titolo: Allunaggio
Piattaforma: TI99/4A
Linguaggio: TI Exetended Basic
Versione originale: Lucio Omiccioli
Pubblicazione: PC Personal Computer
Anno: 7 Novembre1983
Trascrizione: Francesco Fiorentini
Anno: 2026
Download: N/A
Note: N/A

Istruzioni:
Simulazione di atterraggio lunare
Vi trovate nella cabina di controllo di un simulatore di atterraggio lunare e dovete decidere i passi corretti per la manovra di atterraggio.
Il vostro compito e’di dire al calcolatore la quantita’ di carburante che, turno per turno, desiderate bruciare per rallentare la caduta sulla luna (min 8-max 200 kg).
Scopo del gioco e’ di evitare di schiantarsi sulla luna oppure di partire per la tangente e perdersi nello spazio profondo.

Qui di seguito trovate il codice da copiare sul vostro TI99/4A oppure su un emulatore, noi suggeriamo Classic99.

Di seguito le istruzioni per caricare il listato sull’emulatore Classic99:
– Copiare il listato di cui sotto
– Avviare l’emulatore
– Da Cartridge -> Apps, selezionare Basic
– Premere un tasto qualsiasi
– Dopodiché premere 2 per avviare il TI Extended Basic
– Dal comando Edit, selezionare Paste per incollare il listato
– Digitare RUN per eseguire il codice
Buon divertimento!

Attenzione – Ci siamo resi conto che nel listato i caratteri ‘>’ e ‘<‘ potrebbero venir sostituiti dai rispettivi encoding html ‘&gt’ e ‘&lt’. Nel caso, sostituite questi valori nel listato prima di copiarlo sull’emulatore.

Listato: Allunaggio – TI99/4A – TI Basic

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
100 REM ****************************

110 REM BY LUCIO OMICCIOLI-7.11.1983

120 REM ****************************

130 CALL CLEAR::GOSUB 480

140 CALL CLEAR::TM=0::S0=120000::V0=1000::CARB=1600::X=0::Y=0::Z=0

150 DISPLAY AT(1,1):" T    H       V     CARB IMP.C"

160 DISPLAY AT(2,1):"------------------------------"

170 GOTO 200

180 DISPLAY AT(24,1):"CARBURANTE PER RAZZI(KG)"

190 ACCEPT AT(24,25):Y::IF Y<8 AND Y>0 OR Y>200 OR Y<0 THEN 180

200 IMAGE ### ###.## ####.# #### K=###

210 DISPLAY AT(3,1):USING 200:TM,S0/1000,V0*3.6,CARB,Y

220 CARB=CARB-Y

230 V0=V0+16.2-Y

240 S0=S0-V0*10+50*(1.62-Y*0.1)

250 TM=TM+10::X=X+1::IF X>19 THEN X=0

260 IF CARB<=0 THEN CARB=0

270 IF V0<-100 THEN 390

280 IF S0<0 THEN 310

290 IF S0<1000 AND V0<100 THEN 440

300 GOTO 180

310 CALL CLEAR::TM=TM+S0/V0::Z=Y*S0/V0/10::CARB=CARB-Z::V0=V0+1.62*10-Z

320 DISPLAY AT(1,1):"SULLA LUNA DOPO";INT(TM);"SEC"

330 DISPLAY AT(3,1):"VELOCITA' DI IMPATTO";INT(V0*3.6);"KM/H"

340 DISPLAY AT(5,1):"SCORTA CARBURANTE";INT(CARB);"KG"

350 DISPLAY AT(7,1):"SPIACENTE NESSUN SOPRAVVISSUTO"

360 DISPLAY AT(9,1):"HAI PRODOTTO SULLA LUNA UN CRATERE DELLA LARGHEZZA"

370 DISPLAY AT(11,1):"DI";INT(V0*2);"METRI CIRCA"

380 DISPLAY AT(24,1):"GIOCHI ANCORA (S/N)"::ACCEPT AT(24,21):K$::IF K$<>"S" THEN END ELSE 140

390 CALL CLEAR::DISPLAY AT(1,1):"VERSO LO SPAZIO DOPO";TM;"SEC"

400 DISPLAY AT(3,1):"VELOCITA' DI FUGA ";INT(V0*3.6);"KM/H"

410 DISPLAY AT(5,1):"SCORTA CARBURANTE";CARB;"KG"

420 DISPLAY AT(7,1):"SPIACENTE NESSUN SOPRAVVISSUTO"

430 DISPLAY AT(24,1):"GIOCHI ANCORA (S/N)"::ACCEPT AT(24,21):K$::IF K$<>"S" THEN END ELSE 140

440 CALL CLEAR

450 DISPLAY AT(2,1):"MISSIONE COMPIUTA,SEI RIUSCITO AD ATTERRARE DOPO ";TM;"SEC"

460 DISPLAY AT(6,1):"SCORTA DI CARBURANTE";CARB;"KG"

470 DISPLAY AT(24,1):"GIOCHI ANCORA (S/N)"::ACCEPT AT(24,21):K$::IF K$<>"S" THEN END ELSE 140

480 DISPLAY AT(1,1):"****************************"

490 DISPLAY AT(24,1):"****************************"

500 DISPLAY AT(2,1):"SIMULAZIONE DI ATTERRAGGIO LUNARE"

510 DISPLAY AT(5,1):"VI TROVATE NELLA CABINA DI CONTROLLO DI UN SIMULATORE DI ATTERRAGGIO LUNARE E DOVETE DECIDERE I PASSI"

520 DISPLAY AT(9,1):"CORRETTI PER LA MANOVRA DI ATTERRAGGIO"

530 DISPLAY AT(12,1):"IL VOSTRO COMPITO E'DI DIRE AL CALCOLATORE LA QUANTITA' DI CARBURANTE CHE,TURNO PER TURNO,DESIDERATE BRUCIARE"

540 DISPLAY AT(16,1):"PER RALLENTARE LA CADUTA SULLA LUNA (MIN 8-MAX 200 KG)"

550 DISPLAY AT(19,1):"SCOPO DEL GIOCO E DI EVITARE DI SCHIANTARSI SULLA LUNA"

560 DISPLAY AT(23,1):"PREMI *ENTER* PER CONTINUARE"

570 ACCEPT AT(23,28):G$

580 RETURN